Schedule periodic tasks inside your Micronaut applications

Learn how to schedule periodic tasks inside your Micronaut microservices.

Authors: Sergio del Amo

Micronaut Version: 1.0.0.M2

1 Getting Started

Nowadays it is pretty usual to have some kind of cron or scheduled task that needs to run every midnight, every hour, a few times a week,…​

In this guide you will learn how to use Micronaut native capabilities to schedule periodic tasks inside a Micronaut microservice.

1.1 What you will need

To complete this guide, you will need the following:

  • Some time on your hands

  • A decent text editor or IDE

  • JDK 1.8 or greater installed with JAVA_HOME configured appropriately

1.2 Solution

We recommend you to follow the instructions in the next sections and create the app step by step. However, you can go right to the completed example.

or

Then, cd into the complete folder which you will find in the root project of the downloaded/cloned project.

2 Writing the Application

Create a Groovy Micronaut app using the Micronaut Command Line Interface.

mn create-app example.micronaut.complete --features=groovy

The previous command createas a micronaut app with the default package example.micronaut in a folder named complete.

Due to the --features groovy flag, it generates a Groovy Micronaut app and it uses Gradle build system. However, you could use other build tool such as Maven or other programming languages such as Java or Kotlin.

2.1 Set log level INFO for package demo

During this guide, we are going to use several log statements to show Job execution.

Add at the end of logback.xml the next statement:

src/main/resources/logback.xml
<configuration>
...
..
.
    <logger name="example.micronaut" level="info" />
</configuration>

The above line configures a logger for package example.micronaut with log level INFO.

2.2 Creating a Job

Create a file and add the following:

src/main/groovy/example/micronaut/HelloWorldJob.groovy
package example.micronaut

import groovy.util.logging.Slf4j
import io.micronaut.scheduling.annotation.Scheduled
import javax.inject.Singleton
import java.text.SimpleDateFormat
import groovy.transform.CompileStatic

@CompileStatic
@Singleton (1)
@Slf4j (2)
class HelloWorldJob {

    @Scheduled(fixedDelay = "10s") (3)
    void executeEveryTen() {
        log.info("Simple Job every 10 seconds :{}", new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }

    @Scheduled(fixedDelay = "45s", initialDelay = "5s") (4)
    void executeEveryFourtyFive() {
        log.info("Simple Job every 45 seconds :{}", new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }
}
1 To register a Singleton in Micronaut’s application context annotate your class with javax.inject.Singleton
2 @Slf4j local transform adds a logging ability to the bean.
3 Create trigger every 10 seconds
4 Create another trigger every 45 seconds with an initial delay of 5 seconds (5000 millis)

 

Now start the application:

./gradlew run

And after a few seconds you will see the following output:

---
... Simple Job every 10 seconds :15/5/2018 12:48:02 (1)
... Simple Job every 45 seconds :15/5/2018 12:48:07 (2)
... Simple Job every 10 seconds :15/5/2018 12:48:12 (3)
... Simple Job every 10 seconds :15/5/2018 12:48:22
... Simple Job every 10 seconds :15/5/2018 12:48:32
... Simple Job every 10 seconds :15/5/2018 12:48:42
... Simple Job every 45 seconds :15/5/2018 12:48:52 (4)
... Simple Job every 10 seconds :15/5/2018 12:48:52

1 First execution of 10 seconds job just after the application starts
2 The 45 seconds job just starts 5 seconds after the app starts
3 Second execution of 10 seconds job just 10 seconds after the first execution
4 Second execution of 45 seconds job just 45 seconds after the first execution

2.3 Business logic in dedicated Use Cases

Although the previous example is valid, usually you don’t want to put your business logic in a Job. A better approach is to create an additional bean which the Job invokes. This approach decouples your business logic from the scheduling logic. Moreover, it facilities testing and maintenance. Let’s see an example:

Create the following use case:

src/main/groovy/example/micronaut/EmailUseCase.groovy
package example.micronaut

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import javax.inject.Singleton
import java.text.SimpleDateFormat

@Slf4j
@CompileStatic
@Singleton
class EmailUseCase {

    void send(String user, String message) {
        log.info("Sending email to {} : {} at {}", user, message, new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }
}

And then the job:

src/main/groovy/example/micronaut/DailyEmailJob.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.scheduling.annotation.Scheduled
import javax.inject.Singleton

@CompileStatic
@Singleton (1)
class DailyEmailJob {

    protected final EmailUseCase emailUseCase

    DailyEmailJob(EmailUseCase emailUseCase) { (2)
        this.emailUseCase = emailUseCase
    }

    @Scheduled(cron = "0 30 4 1/1 * ?") (3)
    void execute() {
        emailUseCase.send("john.doe@micronaut.example", "Test Message") (4)
    }
}
1 To register a Singleton in Micronaut’s application context annotate your class with javax.inject.Singleton
2 Constructor injection.
3 Trigger the job once a day at 04:30 AM
4 Call the injected use case

2.4 Scheduling a Job Manually

Imagine the following scenario. You want to send every user an email 2 hours after they registered into your app. You want to ask him about his experiences during this first interaction with your application.

For this guide, we are going to schedule a Job to trigger after one minute.

To test it out, we are going to call twice a new use case named RegisterUseCase when the app starts.

Modify Application:

src/main/groovy/example/micronaut/Application.groovy
package example.micronaut

import io.micronaut.context.event.ApplicationEventListener
import io.micronaut.runtime.Micronaut
import groovy.transform.CompileStatic
import io.micronaut.runtime.server.event.ServerStartupEvent
import javax.inject.Singleton

@CompileStatic
@Singleton (1)
class Application implements ApplicationEventListener<ServerStartupEvent> {  (2)

    private final RegisterUseCase registerUseCase

    Application(RegisterUseCase registerUseCase) { (3)
        this.registerUseCase = registerUseCase
    }

    static void main(String[] args) {
        Micronaut.run(Application.class)
    }


    @Override
    void onApplicationEvent(ServerStartupEvent event) { (4)
        try {
            registerUseCase.register("harry@micronaut.example")
            Thread.sleep(20000)
            registerUseCase.register("ron@micronaut.example")
        } catch (InterruptedException e) {
            e.printStackTrace()
        }
    }
}
1 Annotate Application.groovy with @Singleton to register it in the application context.
2 Listen to the event ServerStartupEvent
3 Constructor injection of RegisterUseCase
4 onApplicationEvent is invoked when the app starts.

 

As you see in the previous example, subscribing to an event is as easy as implementing ApplicationEventListener.

Create a runnable task EmailTask.groovy

src/main/groovy/example/micronaut/EmailTask.groovy
package example.micronaut

import groovy.transform.CompileStatic

@CompileStatic
class EmailTask implements Runnable {

    String email
    String message
    EmailUseCase emailUseCase

    @Override
    void run() {
        emailUseCase.send(email, message)
    }
}

Create RegisterUseCase.groovy which schedules the previous task.

src/main/groovy/example/micronaut/RegisterUseCase.groovy
package example.micronaut

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import io.micronaut.scheduling.TaskExecutors
import io.micronaut.scheduling.TaskScheduler
import javax.inject.Named
import javax.inject.Singleton
import java.text.SimpleDateFormat
import java.time.Duration

@CompileStatic
@Slf4j
@Singleton
class RegisterUseCase {

    protected final TaskScheduler taskScheduler
    protected final EmailUseCase emailUseCase

    RegisterUseCase(EmailUseCase emailUseCase, (1)
                           @Named(TaskExecutors.SCHEDULED) TaskScheduler taskScheduler) { (2)
        this.emailUseCase = emailUseCase
        this.taskScheduler = taskScheduler
    }

    void register(String email) {
        log.info("saving {} at {}", email, new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
        scheduleFollowupEmail(email, "Welcome to Micronaut")
    }

    private void scheduleFollowupEmail(String email, String message) {
        EmailTask task = new EmailTask(emailUseCase: emailUseCase, email: email, message: message) (3)
        taskScheduler.schedule(Duration.ofMinutes(1), task) (4)
    }
}
1 Constructor injection of EmailUseCase
2 Inject the TaskScheduler bean
3 Create a Runnable task.
4 Schedule the task to run a minute from now.

If you execute the above code you will see the Job being executed one minute after we schedule it and with the supplied email address.

INFO  example.micronaut.RegisterUseCase - saving harry@micronaut.example at 15/5/2018 06:25:14
INFO  example.micronaut.RegisterUseCase - saving ron@micronaut.example at 15/5/2018 06:25:34
INFO  example.micronaut.EmailUseCase - Sending email to harry@micronaut.example : Welcome to Micronaut at 15/5/2018 06:26:14
INFO  example.micronaut.EmailUseCase - Sending email to ron@micronaut.example : Welcome to Micronaut at 15/5/2018 06:26:34

3 Summary

During this guide, we learned how to configure Jobs using the @Scheduled annotation using fixedDelay, initialDelay, and cron as well as manually configuring jobs with a TaskScheduler and tasks.