Micronaut JWT authentication via Cookies

Learn how to secure a Micronaut app using JWT (JSON Web Token) based authentication where the JWT tokens are transported via Cookies.

Authors: Sergio del Amo

Micronaut Version: 1.0.0.M4

1 Getting Started

In this guide you are going to setup JWT based authentication and configure it so that JWT tokens are transported and read via Cookies.

The following sequence illustrates the authentication flow:

jwt cookie

1.1 What you will need

To complete this guide, you will need the following:

  • Some time on your hands

  • A decent text editor or IDE

  • JDK 1.8 or greater installed with JAVA_HOME configured appropriately

1.2 How to complete the guide

We recommend you to follow the instructions in the next sections and create the app step by step. However, you can go right to the completed example.

or

Then, cd into the complete folder which you will find in the root project of the downloaded/cloned project.

2 Writing the Application

Create a Groovy Micronaut app using the Micronaut Command Line Interface.

mn create-app example.micronaut.complete --features=groovy

The previous command createas a micronaut app with the default package example.micronaut in a folder named complete.

Due to the --features groovy flag, it generates a Groovy Micronaut app and it uses Gradle build system. However, you could use other build tool such as Maven or other programming languages such as Java or Kotlin.

2.1 Security Dependency

Add Micronaut’s JWT security dependency to your build file.

build.gradle
dependencies {
...
..
.
    compile "io.micronaut:security-jwt"
}

2.2 Configuration

Add the next block to the configuration file:

src/main/resources/application.yaml
micronaut:
    application:
        name: complete
micronaut:
  security:
    enabled: true (1)
    endpoints:
      login:
        enabled: true (2)
      logout:
        enabled: true (3)
    token:
      jwt:
        enabled: true (4)
        bearer:
          enabled: false (5)
        cookie:
          enabled: true (6)
          loginFailureTargetUrl: /login/authFailed (7)
        signatures:
          secret:
            generator:  (8)
              secret: pleaseChangeThisSecretForANewOne (9)
1 Enable Micronaut’s security capabilities
2 Expose /login endpoint
3 Expose /logout endpoint
4 Enable JWT based authentication
5 Disable Bearer Token support.
6 Enable Cookie Token support.
7 If the login fails, redirect to /login/authFailed
8 You can create a SecretSignatureConfiguration named generator via configuration as illustrated above. The generator signature is used to sign the issued JWT claims.
9 Change this by your own secret and keep it safe.

2.3 Authentication Provider

To keep this guide simple, create a naive AuthenticationProvider to simulate user’s authentication.

src/main/groovy/example/micronaut/services/AuthenticationProviderUserPassword.groovy
package example.micronaut.services

import groovy.transform.CompileStatic
import io.micronaut.security.authentication.AuthenticationFailed
import io.micronaut.security.authentication.AuthenticationProvider
import io.micronaut.security.authentication.AuthenticationRequest
import io.micronaut.security.authentication.AuthenticationResponse
import io.micronaut.security.authentication.UserDetails
import io.reactivex.Flowable
import org.reactivestreams.Publisher
import javax.inject.Singleton

@CompileStatic
@Singleton (1)
class AuthenticationProviderUserPassword implements AuthenticationProvider { (2)

    @Override
    Publisher<AuthenticationResponse> authenticate(AuthenticationRequest authenticationRequest) {
        if ( authenticationRequest.identity == "sherlock" &&
                authenticationRequest.secret == "password") {
            UserDetails userDetails = new UserDetails((String) authenticationRequest.identity, [])
            return Flowable.just(userDetails)  as Publisher<AuthenticationResponse>
        }
        Flowable.just(new AuthenticationFailed()) as Publisher<AuthenticationResponse>
    }
}
1 To register a Singleton in Micronaut’s application context annotate your class with javax.inject.Singleton
2 A Micronaut’s Authentication Provider implements the interface io.micronaut.security.authentication.AuthenticationProvider

2.4 Apache Velocity

By default, Micronaut’s controllers produce JSON. Usually, you consume those endpoints with a mobile phone application or a Javascript front end (Angular, React, Vue.js …​). However, to keep this guide simple we are going to produce HTML in our controllers.

In order to do that, we use Apache Velocity.

Velocity is a Java-based template engine. It permits anyone to use a simple yet powerful template language to reference objects defined in Java code.

Add a dependency to Micronaut’s Server Side View Rendering Module and to Velocity:

build.gradle
dependencies {
...
..
.
    compile "io.micronaut:views"
    runtime "org.apache.velocity:velocity-engine-core:2.0"
}

Create two velocity templates in src/main/resources/views:

src/main/resources/views/home.vm
<!DOCTYPE html>
<html>
    <head>
        <title>Home</title>
    </head>
    <body>
        #if( $loggedIn )
            <h1>username: <span>$username</span></h1>
        #else
            <h1>You are not logged in</h1>
        #end
        #if( $loggedIn )
            <form action="logout" method="POST">
                <input type="submit" value="Logout"/>
            </form>
        #else
            <p><a href="/login/auth">Login</a></p>
        #end
    </body>
</html>
src/main/resources/views/auth.vm
<!DOCTYPE html>
<html>
    <head>
        #if( $errors )
            <title>Login Failed</title>
        #else
            <title>Login</title>
        #end
    </head>
<body>
    <form action="/login" method="POST">
        <ol>
            <li>
                <label for="username">Username</label>
                <input type="text" name="username" id="username"/>
            </li>
            <li>
                <label for="password">Password</label>
                <input type="password" name="password" id="password"/>
            </li>
            <li>
                <input type="submit" value="Login"/>
            </li>
            #if( $errors )
                <li id="errors">
                    <span style="color: red;">Login Failed</span>
                </li>
            #end
        </ol>
    </form>
</body>
</html>

2.5 Controllers

Create a file named HomeController which resolves the base URL /:

src/main/groovy/example/micronaut/controllers/HomeController.groovy
package example.micronaut.controllers


import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.Secured
import io.micronaut.views.View

import javax.annotation.Nullable
import java.security.Principal

@CompileStatic
@Secured("isAnonymous()") (1)
@Controller("/") (2)
class HomeController {

    @Get("/") (3)
    @View("home") (4)
    Map<String, Object> index(@Nullable Principal principal) { (6)
        Map<String, Object> data = [:]
        data["loggedIn"] = principal != null
        if (principal) {
            data["username"] = principal.name
        }
        data
    }
}
1 Annotate with io.micronaut.security.Secured to configure security access. Use isAnonymous() expression for anonymous access.
2 Annotate with io.micronaut.http.annotation.Controller to designate a class as a Micronaut’s controller.
3 You can specify the HTTP verb for which a controller’s action responds to. To respond to a GET request, use io.micronaut.http.annotation.Get.
4 Use View annotation to specify which template would you like to render the response against.
5 If you are authenticated, you can use the java.security.Principal as a parameter type. For parameters which maybe null, use javax.annotation.Nullable.

Login Form

Next, create LoginAuthController which renders the login form.

src/main/groovy/example/micronaut/controllers/LoginAuthController.groovy
package example.micronaut.controllers

import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.Secured
import io.micronaut.views.View

@CompileStatic
@Secured("isAnonymous()") (1)
@Controller("/login") (2)
class LoginAuthController {

    @Get("/auth") (3)
    @View("auth") (4)
    Map<String, Object> auth() {
        [:]
    }

    @Get("/authFailed") (5)
    @View("auth")  (4)
    Map<String, Object> authFailed() {
        [errors: true] as Map<String, Object>
    }
}
1 Annotate with io.micronaut.security.Secured to configure security access. Use isAnonymous() expression for anonymous access.
2 Annotate with io.micronaut.http.annotation.Controller to designate a class as a Micronaut’s controller.
3 responds to GET requests at /login/auth
4 Use View annotation to specify which template would you like to render the response against.
5 responds to GET requests at /login/authFailed

3 Tests

We use also, Geb; a browser automation solution.

To use Geb, add dependencies:

build.gradle
dependencies {
...
..
.
    testCompile "org.gebish:geb-spock:2.1"
    testRuntime "org.seleniumhq.selenium:selenium-chrome-driver:3.6.0"
    testRuntime "org.seleniumhq.selenium:selenium-firefox-driver:3.6.0"
    testCompile "org.seleniumhq.selenium:selenium-support:3.6.0"
    testCompile "org.seleniumhq.selenium:selenium-api:3.6.0"
}

Create a Geb Configuration file to setup different environments:

import org.openqa.selenium.chrome.ChromeDriver
import org.openqa.selenium.chrome.ChromeOptions
import org.openqa.selenium.firefox.FirefoxDriver
import org.openqa.selenium.firefox.FirefoxOptions

environments {

    // run via “./gradlew -Dgeb.env=chrome test”
    chrome {
        driver = { new ChromeDriver() }
    }

    // run via “./gradlew -Dgeb.env=chromeHeadless test”
    chromeHeadless {
        driver = {
            ChromeOptions o = new ChromeOptions()
            o.addArguments('headless')
            new ChromeDriver(o)
        }
    }

    firefoxHeadless {
        driver = {
            FirefoxOptions o = new FirefoxOptions()
            o.addArguments('-headless')
            new FirefoxDriver(o)
        }
    }

    // run via “./gradlew -Dgeb.env=firefox test”
    firefox {
        driver = { new FirefoxDriver() }
    }
}

Geb uses the Page concept pattern - The Page Object Pattern gives us a common sense way to model content in a reusable and maintainable way.

Create two pages:

src/test/groovy/example/micronaut/HomePage.groovy
package example.micronaut

import geb.Page

class HomePage extends Page {

    static url = '/'

    static at = { title == 'Home' }

    static content = {
        loginLink { $('a', text: 'Login') }
        logoutButton { $('input', type: 'submit', value: 'Logout') }
        usernameElement(required: false) { $('h1 span', 0) }
    }

    String username() {
        if ( usernameElement.empty ) {
            return null
        }
        usernameElement.text()
    }

    void login() {
        loginLink.click()
    }

    void logout() {
        logoutButton.click()
    }
}
src/test/groovy/example/micronaut/LoginPage.groovy
package example.micronaut

import geb.Page

class LoginPage extends Page {

    static url = '/login/auth'

    static at = { title.contains 'Login' }

    static content = {
        usernameInput { $('#username') }
        passwordInput { $('#password') }
        submitInput { $('input', type: 'submit') }
        errorsLi(required: false) { $('li#errors') }
    }

    boolean hasErrors() {
        !errorsLi.empty
    }

    void login(String username, String password) {
        usernameInput = username
        passwordInput = password
        submitInput.click()
    }
}

Create a tests which verifies the user authentication flow.

src/test/groovy/example/micronaut/AuthenticationSpec.groovy
class AuthenticationSpec extends GebSpec {

    @Shared
    @AutoCleanup
    EmbeddedServer embeddedServer = ApplicationContext.run(EmbeddedServer)

    @IgnoreIf({ !sys['geb.env'] })
    def "verify session based authentication works"() {
        given:
        browser.baseUrl = "http://localhost:${embeddedServer.port}"

        when:
        to HomePage

        then:
        at HomePage

        when:
        HomePage homePage = browser.page HomePage

        then: 'As we are not logged in, there is no username'
        homePage.username() == null

        when: 'click the login link'
        homePage.login()

        then:
        at LoginPage

        when: 'fill the login form, with invalid credentials'
        LoginPage loginPage = browser.page LoginPage
        loginPage.login('foo', 'foo')

        then: 'the user is still in the login form'
        at LoginPage

        and: 'and error is displayed'
        loginPage.hasErrors()

        when: 'fill the form with valid credentials'
        loginPage.login('sherlock', 'password')

        then: 'we get redirected to the home page'
        at HomePage

        when:
        homePage = browser.page HomePage

        then: 'the username is populated'
        homePage.username() == 'sherlock'

        when: 'click the logout button'
        homePage.logout()

        then: 'we are in the home page'
        at HomePage

        when:
        homePage = browser.page HomePage

        then: 'but we are no longer logged in'
        homePage.username() == null
    }
}

3.1 WebDriver Binaries

Install webdriver-binaries Gradle plugin; a plugin that downloads and caches WebDriver binaries specific to the OS the build runs on.

build.gradle
buildscript {
    repositories {
...
..
    }
    dependencies {
        classpath "gradle.plugin.com.energizedwork.webdriver-binaries:webdriver-binaries-gradle-plugin:1.4"
    }
}

apply plugin:"com.energizedwork.webdriver-binaries"


dependencies {
...
..
.
}

webdriverBinaries {
    chromedriver '2.40'
    geckodriver '0.21.0'
}

tasks.withType(Test) {
    systemProperty "geb.env", System.getProperty('geb.env')
    systemProperty "webdriver.chrome.driver", System.getProperty('webdriver.chrome.driver')
    systemProperty "webdriver.gecko.driver", System.getProperty('webdriver.gecko.driver')
}

4 Testing the Application

To run the tests:

$ ./gradlew -Dgeb.env=chrome test
$ open build/reports/tests/test/index.html

5 Running the Application

To run the application use the ./gradlew run command which will start the application on a random port.