Deploy a Serverless Micronaut function to AWS Lambda Java 11 Runtime

Learn how to distribute a serverless Micronaut Groovy function to AWS Lambda 11 Runtime

Authors: Sergio del Amo

Micronaut Version: 2.0.1

1 Getting Started

Please, read about Micronaut AWS Lambda Support to learn more about different Lambda runtime, Triggers and Handlers and how to integrate with a Micronaut application.

If you want to respond to triggers such as queue events, s3 events or single endpoints you should opt to code your Micronaut functions as Serverless functions.

In this guide, we are going to deploy a Micronaut serverless function to AWS Lambda.

1.1 What you will need

To complete this guide, you will need the following:

  • Some time on your hands

  • A decent text editor or IDE

  • JDK 1.8 or greater installed with JAVA_HOME configured appropriately

You will need also an AWS Account.

1.2 Solution

We recommend you to follow the instructions in the next sections and create the app step by step. However, you can go right to the completed example.

or

Then, cd into the complete folder which you will find in the root project of the downloaded/cloned project.

2 Writing the App

Create a micronaut application with the aws-lambda feature using the CLI:

% mn create-function-app example.micronaut.complete --lang groovy --features aws-lambda
launch

2.1 Code

We want to support a JavaBean as input and output types.

The input is a Book object:

src/main/groovy/example/micronaut/Book.groovy
package example.micronaut
import edu.umd.cs.findbugs.annotations.NonNull
import io.micronaut.core.annotation.Introspected
import javax.validation.constraints.NotBlank
import groovy.transform.CompileStatic

@CompileStatic
@Introspected (1)
class Book {

    @NotBlank (2)
    @NonNull (3)
    String name
}
1 Annotate the class with @Introspected to generate the Bean Metainformation at compile time.
2 name is required
3 Add a nullability annotation to help with Kotlin interoperability and help the IDE.

The output is a BookSaved object:

src/main/groovy/example/micronaut/BookSaved.groovy
package example.micronaut;
import edu.umd.cs.findbugs.annotations.NonNull
import io.micronaut.core.annotation.Introspected
import javax.validation.constraints.NotBlank
import groovy.transform.CompileStatic

@CompileStatic
@Introspected (1)
class BookSaved {

    @NotBlank (2)
    @NonNull (3)
    String name

    @NotBlank (2)
    @NonNull (3)
    String isbn
}
1 Annotate the class with @Introspected to generate the Bean Metainformation at compile time.
2 name and isbn are required
3 Add a nullability annotation to help with Kotlin interoperability and help the IDE.

The application contains a class extending MicronautRequestHandler

src/main/groovy/example/micronaut/BookRequestHandler.groovy
package example.micronaut
import io.micronaut.core.annotation.Introspected
import io.micronaut.function.aws.MicronautRequestHandler

@Introspected
class BookRequestHandler extends MicronautRequestHandler<Book, BookSaved> { (1)

    @Override
    BookSaved execute(Book input) {
        BookSaved bookSaved = new BookSaved()
        bookSaved.with {
            name = input.getName()
            isbn = UUID.randomUUID().toString()
        }
        bookSaved
    }
}
1 The class extends MicronautRequestHandler and defines input and output types.

The generated test shows how the verify the function behaviour:

src/test/groovy/example/micronaut/BookRequestHandlerSpec.groovy
package example.micronaut;
import spock.lang.AutoCleanup
import spock.lang.Shared
import spock.lang.Specification

class BookRequestHandlerSpec extends Specification {

    @AutoCleanup (2)
    @Shared
    BookRequestHandler bookRequestHandler = new BookRequestHandler()  (1)

    void "test Handler"() {
        given:
        Book book = new Book()
        book.name = 'Building Microservices'

        when:
        BookSaved bookSaved = bookRequestHandler.execute(book)  (3)

        then: 'book name matches the one supplied'
        bookSaved.name == book.name

        and: 'isbn is populated'
        bookSaved.isbn
    }
}
1 When you instantiate the Handler, the application context starts.
2 Remember to close your application context when you end your test. You can use your handler to obtain it.
3 Invoke the execute method of the handler.

3 Lambda

3.1 Create Function

Create a Lambda Function. As a runtime, select Java 11 (Correto).

create function

3.2 Upload Code

Generate a FAT JAR of your app with ./gradlew shadowJar and upload it.

upload function code

3.3 Handler

As Handler, set:

example.micronaut.BookRequestHandler

handler

3.4 Test

You can test it easily.

test event

You should see a 200 response:

test result

4 Next Steps

5 Help with Micronaut

Object Computing, Inc. (OCI) sponsored the creation of this Guide. A variety of consulting and support services are available.

OCI is Home to Micronaut.

Meet the Team