Secure a Micronaut application with Github

Learn how to create a Micronaut application and secure it with an Authorization Server provided by Github. Learn how to write your own Authentication Mapper.

Authors: Sergio del Amo

Micronaut Version: 4.4.0

1. Getting Started

In this guide, we will create a Micronaut application written in Groovy.

2. What you will need

To complete this guide, you will need the following:

Some time on your hands
A decent text editor or IDE (e.g. IntelliJ IDEA)
JDK 17 or greater installed with JAVA_HOME configured appropriately

3. Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Download and unzip the source

4. Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide \
    --features=yaml,views-thymeleaf,security-oauth2,security-jwt,reactor,serialization-jackson,http-client \
    --build=maven \
    --lang=groovy \
    --test=spock

If you don’t specify the --build argument, Gradle is used as the build tool.
If you don’t specify the --lang argument, Java is used as the language.
If you don’t specify the --test argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

If you use Micronaut Launch, select Micronaut Application as application type and add yaml, views-thymeleaf, security-oauth2, security-jwt, reactor, serialization-jackson, and http-client features.

If you have an existing Micronaut application and want to add the functionality described here, you can view the dependency and configuration changes from the specified features and apply those changes to your application.

Setup IntelliJ IDEA to develop Micronaut Applications.

4.1. Views

Although the Micronaut framework is primarily designed around message encoding / decoding, there are occasions where it is convenient to render a view on the server side.

We’ll use the Thymeleaf Java template engine to render views.

4.2. Home

Create a controller to handle the requests to /. You will display the email of the authenticated person if any. Annotate the controller endpoint with @View since we will use a Thymeleaf template.

src/main/groovy/example/micronaut/HomeController.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.annotation.Secured
import io.micronaut.security.rules.SecurityRule
import io.micronaut.views.View

@CompileStatic
@Controller (1)
class HomeController {

    @Secured(SecurityRule.IS_ANONYMOUS) (2)
    @View('home') (3)
    @Get (4)
    Map<String, Object> index() {
        [:]
    }
}

1	The class is defined as a controller with the @Controller annotation mapped to the path `/`.
2	Annotate with `io.micronaut.security.Secured` to configure secured access. The `SecurityRule.IS_ANONYMOUS` expression will allow access without authentication.
3	Use View annotation to specify which template to use to render the response.
4	The @Get annotation maps the `index` method to GET `/` requests.

Create a Thymeleaf template:

src/main/resources/views/home.html

<!DOCTYPE html>
<html xmlns:th="http://www.thymeleaf.org">
<head>
    <title>Home</title>
</head>
<body>
<h1>Micronaut - Github example</h1>

<h2 th:if="${security}">username: <span th:text="${security.name}"> </h2>
<h2 th:unless="${security}">username: Anonymous</h2>

<nav>
    <ul>
        <li th:unless="${security}"><a href="/oauth/login/github">Enter</a></li>
        <li th:if="${security}"><a href="/repos">View Repos</a></li>
        <li th:if="${security}"><a href="/logout">Logout</a></li>
    </ul>
</nav>
</body>
</html>

Also, note that we return an empty model in the controller. However, we are accessing security in the Thymeleaf template.

The SecurityViewModelProcessor injects into the model a security map with the authenticated user. See User in a view documentation.

4.3. GitHub OAuth App

To provide authentication, create a GitHub OAuth App.

4.4. OAuth 2.0 Configuration

Add the following OAuth2 Configuration:

Since Micronaut Framework 4.0, to use YAML configuration, you have to add the YAML dependency.

src/main/resources/application.yml

micronaut:
  security:
    authentication: cookie (1)
    token:
      jwt:
        signatures:
          secret:
            generator: (2)
              secret: '"${JWT_GENERATOR_SIGNATURE_SECRET:pleaseChangeThisSecretForANewOne}"' (3)
    oauth2:
      clients:
        github: (4)
          client-id:  '${OAUTH_CLIENT_ID:xxx}' (5)
          client-secret: '${OAUTH_CLIENT_SECRET:yyy}' (6)
          scopes: (7)
            - user:email
            - read:user
            - public_repo
          authorization:
            url: 'https://github.com/login/oauth/authorize' (8)
          token:
            url: 'https://github.com/login/oauth/access_token' (9)
            auth-method: CLIENT_SECRET_POST
    endpoints:
      logout:
        get-allowed: true (10)

1	Once validated, we will save the ID Token in a Cookie. To read in subsequent requests, set `micronaut.security.authentication` to `cookie`.
2	You can create a SecretSignatureConfiguration named `generator` via configuration as illustrated above. The `generator` signature is used to sign the issued JWT claims.
3	Change this to your own secret and keep it safe (do not store this in your VCS).
4	The provider identifier must match the last part of the URL you entered as a redirect URL: `/oauth/callback/github`.
5	Client Secret. See previous screenshot.
6	Client ID. See previous screenshot.
7	Specify the scopes you want to request. GitHub Scopes let you sepcify exactly what type of access you need.
8	Map manually the GitHub Authorization endpoint.
9	Map manually the Github Token endpoint.
10	Accept GET request to the `/logout` endpoint.

The previous configuration uses several placeholders. You will need to set up OAUTH_CLIENT_ID, OAUTH_CLIENT_SECRET environment variables.

export OAUTH_CLIENT_ID=XXXXXXXXXX
export OAUTH_CLIENT_SECRET=YYYYYYYYYY

4.5. User Details Mapper

Here is a high level diagram of how the authorization code grant flow works with an OAuth 2.0 provider such as GitHub.

We need an HTTP Client to retrieve the user info. Create a POJO to represent a GitHub user:

src/main/groovy/example/micronaut/GithubUser.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.serde.annotation.Serdeable

@CompileStatic
@Serdeable
class GithubUser {

    final String login
    final String name
    final String email

    GithubUser(String login, String name, String email) {
        this.login = login
        this.name = name
        this.email = email
    }
}

Then, create a Micronaut Declarative HTTP Client to consume GitHub REST API v3

src/main/groovy/example/micronaut/GithubApiClient.groovy

package example.micronaut

1	GitHub encourages explicitly requesting version 3 via the Accept header. With `@Header`, you add the `Accept: application/vnd.github.v3+json` HTTP header to every request.
2	Add the id `githubv3` to the `@Client` annotation. Later, you will provide URL for this client id.
3	Define a HTTP GET request to `/user` endpoint.
4	You can return reactive types in a Micronaut declarative HTTP client.
5	You can specify that a parameter binds to a HTTP Header such as the Authorization header.

Specify the URL for the githubv3 service.

src/main/resources/application.yml

micronaut:
  http:
    services:
      githubv3:
        url: "https://api.github.com"

For GitHub we need to provide a Authentication Mapper. The easiest way is to create a bean which implements OauthAuthenticationMapper.

src/main/groovy/example/micronaut/GithubAuthenticationMapper.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.core.annotation.Nullable
import io.micronaut.security.authentication.AuthenticationResponse
import io.micronaut.security.oauth2.endpoint.authorization.state.State
import io.micronaut.security.oauth2.endpoint.token.response.OauthAuthenticationMapper
import io.micronaut.security.oauth2.endpoint.token.response.TokenResponse
import jakarta.inject.Named
import jakarta.inject.Singleton
import org.reactivestreams.Publisher
import reactor.core.publisher.Mono

@CompileStatic
@Named('github') (1)
@Singleton
class GithubAuthenticationMapper implements OauthAuthenticationMapper {

    public static final String TOKEN_PREFIX = 'token '
    public static final String ROLE_GITHUB = 'ROLE_GITHUB'

    private final GithubApiClient apiClient

    GithubAuthenticationMapper(GithubApiClient apiClient) {
        this.apiClient = apiClient
    }

    @Override
    Publisher<AuthenticationResponse> createAuthenticationResponse(TokenResponse tokenResponse,
                                                                   @Nullable State state) {
        return Mono.from(apiClient.getUser(TOKEN_PREFIX + tokenResponse.accessToken)) (2)
                .map(user -> AuthenticationResponse.success(user.login,
                        Collections.singletonList(ROLE_GITHUB),
                        Collections.singletonMap(ACCESS_TOKEN_KEY, tokenResponse.accessToken) as Map)) as Publisher (3)
    }
}

1	Usa a name qualifier for the bean which matches the name you used in the OAuth 2.0 configuration in `application.yml`
2	Consume the `/user` endpoint with the Micronaut HTTP Client.
3	Save the original GitHub access token in a claim. We will use it to contact GitHub’s API later.

4.6. Retrieve User GitHub repositories

With the access token, we retrieved during the login we will contact the GitHub API to fetch the user’s repositories.

First, create a POJO to represent a GitHub repository:

src/main/groovy/example/micronaut/GithubRepo.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.serde.annotation.Serdeable

@CompileStatic
@Serdeable
class GithubRepo {

    final String name

    GithubRepo(String name) {
        this.name = name
    }
}

Add a method to GithubApiClient

src/main/groovy/example/micronaut/GithubApiClient.groovy

    @Get('/user/repos{?sort,direction}') (1)
    List<GithubRepo> repos(
            @Pattern(regexp = 'created|updated|pushed|full_name') @Nullable @QueryValue String sort, (2)
            @Pattern(regexp = 'asc|desc') @Nullable @QueryValue String direction, (2)
            @Header(HttpHeaders.AUTHORIZATION) String authorization)

1	Specify two query values `sort` and `direction`.
2	Annotate `sort` and `direction` as `@Nullable` since they are optional. You can restrict the allowed values with use of constraints.

Create a controller to expose /repos endpoint:

src/main/groovy/example/micronaut/ReposController.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.HttpHeaderValues
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.annotation.Secured
import io.micronaut.security.authentication.Authentication
import io.micronaut.security.rules.SecurityRule
import io.micronaut.views.View

import static io.micronaut.security.oauth2.endpoint.token.response.OauthAuthenticationMapper.ACCESS_TOKEN_KEY

@CompileStatic
@Controller('/repos') (1)
class ReposController {

    public static final String CREATED = 'created'
    public static final String DESC = 'desc'
    public static final String REPOS = 'repos'

    private final GithubApiClient githubApiClient

    ReposController(GithubApiClient githubApiClient) {
        this.githubApiClient = githubApiClient
    }

    @Secured(SecurityRule.IS_AUTHENTICATED) (2)
    @View('repos') (3)
    @Get (4)
    Map<String, Object> index(Authentication authentication) {
        List<GithubRepo> repos = githubApiClient.repos(CREATED, DESC, authorizationValue(authentication))  (5)
        return [(REPOS): repos] as Map
    }

    private String authorizationValue(Authentication authentication) {
        Object claim = authentication.attributes[ACCESS_TOKEN_KEY]  (6)
        if (claim instanceof String) {
            return HttpHeaderValues.AUTHORIZATION_PREFIX_BEARER + ' ' + claim
        }
        return null
    }
}

1	Qualify the `@Controller` annotation with `/repos` to designate the endpoint URL.
2	We want this endpoint to be only accessible to authenticated users.
3	We specify the view name `repos` which renders the model.
4	Declare a GET endpoint.
5	Consume the GitHub API.
6	Use the previously obtained access token to get access against the GitHub API.

Create a Thymeleaf template:

src/main/resources/views/repos.html

<!DOCTYPE html>
<html xmlns:th="http://www.thymeleaf.org">
<head>
    <title>Home</title>
</head>
<body>
<h1><a href="/">Home</a> &rarr; Repositories</h1>
<nav>
    <ul th:each="repo: ${repos}">
        <li th:text="${repo.name}"/>
    </ul>
</nav>
</body>
</html>

5. Running the Application

To run the application, use the ./mvnw mn:run command, which starts the application on port 8080.

6. Next steps

Read Micronaut OAuth 2.0 documentation to learn more.

7. Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

8. License

All guides are released with an Apache license 2.0 license for the code and a Creative Commons Attribution 4.0 license for the writing and media (images…).

Table of Contents