Groovy / Maven

Localize your application

Respond to a localized version of your application with LocalizedMessageSource.

Sergio del Amo
On this guide
In this section

Getting Started

In this guide, we will create a Micronaut application written in Groovy.

What you will need

To complete this guide, you will need the following:

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide \
    --features= \
    --build=maven \
    --lang=groovy \
    --test=spock
Note
 If you don’t specify the --build argument, Gradle with the Kotlin DSL is used as the build tool.
If you don’t specify the --lang argument, Java is used as the language.
If you don’t specify the --test argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

If you use Micronaut Launch, select Micronaut Application as application type and add features.

Note
 If you have an existing Micronaut application and want to add the functionality described here, you can view the dependency and configuration changes from the specified features, and apply those changes to your application.

Diff

Setup IntelliJ IDEA to develop Micronaut Applications.

Properties

Create a default messages.properties file:

src/main/resources/i18n/messages.properties
hello.world=Hello World

Create a messages_es.properties file for Spanish locale:

src/main/resources/i18n/messages_es.properties
hello.world=Hola Mundo

Message Source

Create a MessageSource that uses the previous properties files:

groovy/src/main/groovy/example/micronaut/MessageSourceFactory.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.context.MessageSource
import io.micronaut.context.annotation.Factory
import io.micronaut.context.i18n.ResourceBundleMessageSource
import jakarta.inject.Singleton

@CompileStatic
@Factory // 
class MessageSourceFactory {
    @Singleton // 
    MessageSource createMessageSource() {
        return new ResourceBundleMessageSource('i18n.messages')
    }
}
1 A class annotated with the @Factory annotated is a factory. It provides one or more methods annotated with a bean scope annotation (e.g. @Singleton). Read more about Bean factories.
2 Use jakarta.inject.Singleton to designate a class as a singleton.

Controller

groovy/src/main/groovy/example/micronaut/HelloWorldController.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.context.LocalizedMessageSource
import io.micronaut.http.MediaType
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.http.annotation.Produces

@CompileStatic
@Controller // 
class HelloWorldController {

    private final LocalizedMessageSource messageSource

    HelloWorldController(LocalizedMessageSource messageSource) { // 
        this.messageSource = messageSource
    }

    @Produces(MediaType.TEXT_PLAIN) // 
    @Get // 
    Optional<String> index() { // 
        return messageSource.getMessage('hello.world') // 
    }
}
1 The class is defined as a controller with the @Controller annotation mapped to the path /.
2 Use constructor injection to inject a bean of type LocalizedMessageSource.
3 Set the response content-type to text/plain with the @Produces annotation.
4 LocalizedMessageSource contains methods to fetch a message with a code, a default message, or variables.

Tests

groovy/src/test/groovy/example/micronaut/HelloWorldControllerSpec.groovy
package example.micronaut

import io.micronaut.http.HttpHeaders
import io.micronaut.http.HttpRequest
import io.micronaut.http.client.BlockingHttpClient
import io.micronaut.http.client.HttpClient
import io.micronaut.http.client.annotation.Client
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject
import spock.lang.Specification

@MicronautTest // 
class HelloWorldControllerSpec extends Specification {

    @Inject
    @Client('/') // 
    HttpClient httpClient

    void useOfLocalizedMessageSource() {
        when:
        BlockingHttpClient client = httpClient.toBlocking()
        HttpRequest<?> request = HttpRequest.GET('/')
                .header(HttpHeaders.ACCEPT_LANGUAGE, 'es') // 

        then:
        'Hola Mundo' == client.retrieve(request)

        when:
        request = HttpRequest.GET('/')

        then:
        'Hello World' == client.retrieve(request)
    }
}
1 Annotate the class with @MicronautTest so the Micronaut framework will initialize the application context and the embedded server. More info.
2 Inject the HttpClient bean and point it to the embedded server.
3 Creating HTTP Requests is easy thanks to the Micronaut framework fluid API.

Testing the Application

To run the tests:

./mvnw test

Learn More

The application changes the locale with the Accept-Language HTTP header. Learn more about Locale Resolution.

License

Note
 All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).