Groovy / Gradle

Send Emails with SendGrid from the Micronaut Framework

Learn how to send emails with SendGrid from a Micronaut application.

Sergio del Amo
On this guide
In this section

Getting Started

In this guide, we will create a Micronaut application written in Groovy.

What you will need

To complete this guide, you will need the following:

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide \
    --features=email-sendgrid,validation \
    --build=gradle \
    --lang=groovy \
    --test=spock
Note
 If you don’t specify the --build argument, Gradle with the Kotlin DSL is used as the build tool.
If you don’t specify the --lang argument, Java is used as the language.
If you don’t specify the --test argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

If you use Micronaut Launch, select Micronaut Application as application type and add email-sendgrid, and validation features.

Note
 If you have an existing Micronaut application and want to add the functionality described here, you can view the dependency and configuration changes from the specified features, and apply those changes to your application.

Diff

Setup IntelliJ IDEA to develop Micronaut Applications.

Controller

Create a MailController class. This class uses a collaborator, emailSender, to send an email.

You can send emails asynchronously using the AsyncEmailSender API or synchronously using the EmailSender API.

groovy/src/main/groovy/example/micronaut/MailController.groovy
package example.micronaut

import com.sendgrid.Request
import com.sendgrid.Response
import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import io.micronaut.email.AsyncEmailSender
import io.micronaut.email.Email
import io.micronaut.http.HttpResponse
import io.micronaut.http.annotation.Body
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Post
import org.reactivestreams.Publisher
import reactor.core.publisher.Mono

import static io.micronaut.email.BodyType.HTML

@CompileStatic
@Slf4j
@Controller('/mail') // 
class MailController {

    private final AsyncEmailSender<Request, Response> emailSender

    MailController(AsyncEmailSender<Request, Response> emailSender) { // 
        this.emailSender = emailSender
    }

    @Post('/send') // 
    Publisher<HttpResponse<?>> send(@Body('to') String to) { // 
        Mono.from(emailSender.sendAsync(Email.builder()
                .to(to)
                .subject('Sending email with Twilio Sendgrid is Fun')
                .body('and <em>easy</em> to do anywhere with <strong>Micronaut Email</strong>', HTML)))
                .doOnNext(rsp -> {
                    log.info('response status {}\nresponse body {}\nresponse headers {}',
                            rsp.statusCode, rsp.body, rsp.headers)
                }).map(rsp -> rsp.statusCode >= 400 ?
                HttpResponse.unprocessableEntity() :
                HttpResponse.accepted()) // 
                as Publisher
    }
}
1 The class is defined as a controller with the @Controller annotation mapped to the path /mail/send.
2 Use constructor injection to inject a bean of type AsyncEmailSender.
3 The @Post annotation maps the send method to an HTTP POST request on /mail/send.
4 You can use a qualifier within the HTTP request body. For example, you can use a reference to a nested JSON attribute.
5 Return 202 ACCEPTED as the result if the email delivery succeeds.

Configuration

If you want to send every email with the same address, you can set it via configuration:

src/main/resources/application.properties
micronaut.email.from.email=john@micronaut.example

This is possible thanks to email decorators.

SendGrid

SendGrid is a transactional email service.

SendGrid is responsible for sending billions of emails for some of the best and brightest companies in the world.

SendGrid API Key

To use the Micronaut SendGrid integration, you need an API key.

You need to configure the sendgrid.api-key property. However, don’t put it in application.properties. It’s a password. Expose it via the SENDGRID_API_KEY environment variable, use a secret manager, or create an environment-specific configuration file that will not be included in source version control.

Dependency

Because we added the email-sendgrid feature, the application contains the following dependency:

build.gradle
implementation("com.micronaut.email:micronaut-email-sendgrid")

Test

Create a test bean that replaces the bean of type AsyncTransactionalEmailSender.

groovy/src/test/groovy/example/micronaut/EmailSenderReplacement.groovy
package example.micronaut

import com.sendgrid.Request
import com.sendgrid.Response
import io.micronaut.context.annotation.Replaces
import io.micronaut.context.annotation.Requires
import io.micronaut.email.AsyncEmailSender
import io.micronaut.email.AsyncTransactionalEmailSender
import io.micronaut.email.Email
import io.micronaut.email.EmailException
import jakarta.inject.Named
import jakarta.inject.Singleton
import org.reactivestreams.Publisher
import reactor.core.publisher.Mono

import jakarta.validation.Valid
import jakarta.validation.constraints.NotNull
import java.util.function.Consumer

import static io.micronaut.http.HttpStatus.ACCEPTED

@Requires(property = 'spec.name', value = 'MailControllerSpec') // 
@Singleton
@Replaces(AsyncEmailSender)
@Named(EmailSenderReplacement.NAME)
class EmailSenderReplacement implements AsyncTransactionalEmailSender<Request, Response> {

    public static final String NAME = 'sendgrid'

    final List<Email> emails = []

    @Override
    String getName() {
        NAME
    }

    @Override
    Publisher<Response> sendAsync(@NotNull @Valid Email email,
                                  @NotNull Consumer<Request> emailRequest) throws EmailException {
        emails << email
        Mono.just(new Response(statusCode: ACCEPTED.code))
    }
}
1 Combine @Requires and properties (either via the @Property annotation or by passing properties when starting the context) to avoid bean pollution.

Write a test that uses EmailSenderReplacement to verify that the contents of the email match expectations.

groovy/src/test/groovy/example/micronaut/MailControllerSpec.groovy
package example.micronaut

import io.micronaut.context.BeanContext
import io.micronaut.context.annotation.Property
import io.micronaut.email.AsyncTransactionalEmailSender
import io.micronaut.email.Email
import io.micronaut.http.HttpRequest
import io.micronaut.http.HttpResponse
import io.micronaut.http.client.HttpClient
import io.micronaut.http.client.annotation.Client
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject
import spock.lang.Specification

import static io.micronaut.email.BodyType.HTML
import static io.micronaut.http.HttpStatus.ACCEPTED

@Property(name = 'spec.name', value = 'MailControllerSpec') // 
@MicronautTest // 
class MailControllerSpec extends Specification {

    @Inject
    @Client('/')
    HttpClient httpClient // 

    @Inject
    BeanContext beanContext

    void getMailSendEndpointSendsAnEmail() {

        when:
        HttpResponse<?> response = httpClient.toBlocking().exchange(
                HttpRequest.POST('/mail/send', [to: 'johnsnow@micronaut.example']))

        then:
        ACCEPTED == response.status()

        when:
        AsyncTransactionalEmailSender<?, ?> sender = beanContext.getBean(AsyncTransactionalEmailSender)

        then:
        sender instanceof EmailSenderReplacement

        when:
        EmailSenderReplacement sendgridSender = (EmailSenderReplacement) sender

        then:
        1 == sendgridSender.emails.size()

        when:
        Email email = sendgridSender.emails[0]

        then:
        email.from.email == 'john@micronaut.example'
        email.to
        email.to.first()
        email.to.first().email == 'johnsnow@micronaut.example'
        email.subject == 'Sending email with Twilio Sendgrid is Fun'
        email.body
        email.body.get(HTML).present
        email.body.get(HTML).get() == 'and <em>easy</em> to do anywhere with <strong>Micronaut Email</strong>'
    }
}
1 Combine @Requires and properties (either via the @Property annotation or by passing properties when starting the context) to avoid bean pollution.
2 Annotate the class with @MicronautTest so the Micronaut framework will initialize the application context and the embedded server. More info.
3 Inject the HttpClient bean and point it to the embedded server.

Testing the Application

To run the tests:

./gradlew test

Then open build/reports/tests/test/index.html in a browser to see the results.

Running the Application

API Key

Set the SendGrid API key as an environment variable before you run the application:

export SENDGRID_API_KEY=xxx

From email address

Change the property micronaut.email.from.email to match your SendGrid configuration.

Run

To run the application, use the ./gradlew run command, which starts the application on port 8080.

Invoke

curl -d '{"to":"john@micronaut.example"}' \
     -H "Content-Type: application/json" \
     -X POST http://localhost:8080/mail/send

Next Steps

Explore more features with Micronaut Guides.

Learn more about Micronaut Email integration.

Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

License

Note
 All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).