Groovy / Maven

Micronaut Patterns - Composite

Learn how to use a Composite Pattern if you have multiple beans of particular type

Sergio del Amo
On this guide
In this section

What you will need

To complete this guide, you will need the following:

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Composite Pattern

A common pattern while developing Micronaut applications is to create an ordered functional interface. Often, you want to evaluate every implementation in order. By combining the @Primary annotation and the injection of a collection of beans of a particular type, you achieve this pattern easily in a Micronaut application.

Imagine you want to create an API to resolve a color:

groovy/src/main/groovy/example/micronaut/ColorFetcher.groovy
package example.micronaut

import io.micronaut.core.annotation.NonNull
import io.micronaut.core.order.Ordered
import io.micronaut.http.HttpRequest

@FunctionalInterface // 
interface ColorFetcher extends Ordered { // 

    @NonNull
    Optional<String> favouriteColor(@NonNull HttpRequest<?> request)
}
1 An interface with one abstract method declaration is known as a functional interface. The compiler verifies that all interfaces annotated with @FunctionInterface really contain one and only one abstract method.
2 Implementing the Ordered interface, allows you to easily inject an ordered collection of this type.

Http Header

You may write an implementation which searches for a color in an HTTP header.

groovy/src/main/groovy/example/micronaut/HttpHeaderColorFetcher.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.core.annotation.NonNull
import io.micronaut.http.HttpRequest
import jakarta.inject.Singleton

@CompileStatic
@Singleton // 
class HttpHeaderColorFetcher implements ColorFetcher {

    @Override
    @NonNull
    Optional<String> favouriteColor(@NonNull HttpRequest<?> request) {
        return request.headers.get('color', String)
    }

    @Override
    int getOrder() { // 
        return 10
    }
}
1 Use jakarta.inject.Singleton to designate a class as a singleton.
2 When you override Ordered::getOrder, the lower the number the higher the precedence.

Path

You could have another naive implementation which uses the HTTP Request’s path.

groovy/src/main/groovy/example/micronaut/PathColorFetcher.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.HttpRequest
import jakarta.inject.Singleton

@CompileStatic
@Singleton // 
class PathColorFetcher implements ColorFetcher {

    private static final String[] COLORS = [
            'Red',
            'Blue',
            'Green',
            'Orange',
            'White',
            'Black',
            'Yellow',
            'Purple',
            'Silver',
            'Brown',
            'Gray',
            'Pink',
            'Olive',
            'Maroon',
            'Violet',
            'Charcoal',
            'Magenta',
            'Bronze',
            'Cream',
            'Gold',
            'Tan',
            'Teal',
            'Mustard',
            'Navy Blue',
            'Coral',
            'Burgundy',
            'Lavender',
            'Mauve',
            'Peach',
            'Rust',
            'Indigo',
            'Ruby',
            'Clay',
            'Cyan',
            'Azure',
            'Beige',
            'Turquoise',
            'Amber',
            'Mint'
    ]

    @Override
    Optional<String> favouriteColor(HttpRequest<?> request) {
        return Optional.ofNullable(
                COLORS.findAll { request.path.contains(it.toLowerCase(Locale.ROOT)) }
                      .collect { it.toLowerCase() }[0]
        )
    }

    @Override
    int getOrder() { // 
        return 20
    }
}
1 Use jakarta.inject.Singleton to designate a class as a singleton.
2 When you override Ordered::getOrder, the lower the number the higher the precedence.

Controller

If you create a controller which injects via constructor injection a bean of type ColorFetcher, you will get the following exception:

Message: Multiple possible bean candidates found:
[example.micronaut.PathColorFetcher,
example.micronaut.HttpHeaderColorFetcher]
Path Taken: new ColorController(ColorFetcher colorFetcher)
--> new ColorController([ColorFetcher colorFetcher])
io.micronaut.context.exceptions.DependencyInjectionException:
Failed to inject value for parameter [colorFetcher]
of class: example.micronaut.ColorController
groovy/src/main/groovy/example/micronaut/ColorController.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.core.annotation.NonNull
import io.micronaut.http.HttpRequest
import io.micronaut.http.MediaType
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.http.annotation.Produces

@CompileStatic
@Controller('/color') // 
class ColorController {

    private final ColorFetcher colorFetcher

    ColorController(ColorFetcher colorFetcher) { // 
        this.colorFetcher = colorFetcher
    }

    @Produces(MediaType.TEXT_PLAIN) // 
    @Get('/mint') // 
    Optional<String> mint(@NonNull HttpRequest<?> request) { // 
        return colorFetcher.favouriteColor(request)
    }

    @Produces(MediaType.TEXT_PLAIN) // 
    @Get
    Optional<String> index(@NonNull HttpRequest<?> request) { // 
        return colorFetcher.favouriteColor(request)
    }
}
1 The class is defined as a controller with the @Controller annotation mapped to the path /color.
2 Use constructor injection to inject a bean of type ColorFetcher.
3 By default, a Micronaut response uses application/json as Content-Type. We are returning a String, not a JSON object, so we set it to text/plain with the @Produces annotation.
4 The @Get annotation maps the mint method to an HTTP GET request on /mint.
5 You can bind the HTTP request as a controller method parameter.

Primary

Create a new implementation of ColorFetcher. It traverses every other implementation of ColorFetcher in order.

groovy/src/main/groovy/example/micronaut/CompositeColorFetcher.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.context.annotation.Primary
import io.micronaut.http.HttpRequest
import jakarta.inject.Singleton

@CompileStatic
@Primary // 
@Singleton // 
class CompositeColorFetcher implements ColorFetcher {

    private final List<ColorFetcher> colorFetcherList

    CompositeColorFetcher(List<ColorFetcher> colorFetcherList) { // 
        this.colorFetcherList = colorFetcherList
    }

    @Override
    Optional<String> favouriteColor(HttpRequest<?> request) {
        return Optional.ofNullable(colorFetcherList.collect { it.favouriteColor(request) }
                .findAll { it.isPresent() }
                .collect { it.get() }[0])
    }
}
1 Primary is a qualifier that indicates that a bean is the primary bean to be selected in the case of multiple interface implementations.
2 Use jakarta.inject.Singleton to designate a class as a singleton.
3 ColorFetcher implements Ordered. Because of that, you can inject an ordered list of beans of type ColorFetcher. You get every bean of type ColorFetcher but CompositeColorFetcher.

You can test that CompositeColorFetcher is primary bean of type ColorFetcher.

groovy/src/test/groovy/example/micronaut/CompositeColorFetcherSpec.groovy
package example.micronaut

import io.micronaut.context.BeanContext
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject
import spock.lang.Specification

@MicronautTest(startApplication = false) // 
class CompositeColorFetcherSpec extends Specification {

    @Inject
    BeanContext beanContext

    void compositeColorFetcherIsThePrimaryBeanOfTypeColorFetcher() {
        expect:
        beanContext.getBean(ColorFetcher) instanceof CompositeColorFetcher
    }
}
1 Annotate the class with @MicronautTest so the Micronaut framework will initialize the application context. This test does not need the embedded server. Set startApplication to false to avoid starting it.

Moreover, you can test the previous controller with:

groovy/src/test/groovy/example/micronaut/ColorControllerSpec.groovy
package example.micronaut

import io.micronaut.http.HttpRequest
import io.micronaut.http.client.BlockingHttpClient
import io.micronaut.http.client.HttpClient
import io.micronaut.http.client.annotation.Client
import io.micronaut.http.client.exceptions.HttpClientResponseException
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject
import spock.lang.Specification

@MicronautTest // 
class ColorControllerSpec extends Specification {

    @Inject
    @Client('/')
    HttpClient httpClient // 

    void testCompositePattern() {
        when:
        BlockingHttpClient client = httpClient.toBlocking()

        then:
        'yellow' == client.retrieve(HttpRequest.GET('/color').header('color', 'yellow'))
        'yellow' == client.retrieve(HttpRequest.GET('/color/mint').header('color', 'yellow'))
        'mint' == client.retrieve(HttpRequest.GET('/color/mint'))

        when:
        client.retrieve(HttpRequest.GET('/color'))

        then:
        thrown(HttpClientResponseException)
    }
}
1 Annotate the class with @MicronautTest so the Micronaut framework will initialize the application context and the embedded server. More info.
2 Inject the HttpClient bean and point it to the embedded server.

Next Steps

The Composite pattern is used in several places within the framework. For example:

Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

License

Note
 All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).