Groovy / Maven

Schedule periodic tasks inside your Micronaut applications

Learn how to schedule periodic tasks inside your Micronaut microservices.

Sergio del Amo
On this guide
In this section

Getting Started

In this guide, we will create a Micronaut application written in Groovy.

Nowadays it is pretty usual to have some kind of cron or scheduled task that needs to run every midnight, every hour, a few times a week,…​

In this guide you will learn how to use Micronaut capabilities to schedule periodic tasks inside a Micronaut microservice.

What you will need

To complete this guide, you will need the following:

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide --build=maven --lang=groovy
Note
 If you don’t specify the --build argument, Gradle with the Kotlin DSL is used as the build tool.
If you don’t specify the --lang argument, Java is used as the language.
If you don’t specify the --test argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

Setup IntelliJ IDEA to develop Micronaut Applications.

Set log level INFO for package demo

In this guide, we will use several log statements to show Job execution.

Add this statement to the end of logback.xml:

groovy/src/main/resources/logback.xml
<logger name="example.micronaut" level="INFO"/>

The above line configures a logger for package example.micronaut with log level INFO.

Creating a Job

Create the HelloWorldJob class:

groovy/src/main/groovy/example/micronaut/HelloWorldJob.groovy
package example.micronaut

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import io.micronaut.scheduling.annotation.Scheduled
import jakarta.inject.Singleton
import java.text.SimpleDateFormat

@CompileStatic
@Singleton // 
@Slf4j // 
class HelloWorldJob {

    @Scheduled(fixedDelay = "10s") // 
    void executeEveryTen() {
        log.info("Simple Job every 10 seconds: {}", new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }

    @Scheduled(fixedDelay = "45s", initialDelay = "5s") // 
    void executeEveryFortyFive() {
        log.info("Simple Job every 45 seconds: {}", new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }
}
1 Use jakarta.inject.Singleton to designate a class as a singleton.
2 Inject a Logger.
3 Create trigger every 10 seconds
4 Create another trigger every 45 seconds with an initial delay of 5 seconds (5000 millis)

Now start the application. Execute the ./mvnw mn:run command, which will start the application on port 8080.

After a few seconds, you will see the following output:

... Simple Job every 10 seconds :15/5/2018 12:48:02 
... Simple Job every 45 seconds :15/5/2018 12:48:07 
... Simple Job every 10 seconds :15/5/2018 12:48:12 
... Simple Job every 10 seconds :15/5/2018 12:48:22
... Simple Job every 10 seconds :15/5/2018 12:48:32
... Simple Job every 10 seconds :15/5/2018 12:48:42
... Simple Job every 45 seconds :15/5/2018 12:48:52 
... Simple Job every 10 seconds :15/5/2018 12:48:52
1 First execution of 10 seconds Job after the application starts
2 The 45 seconds Job starts 5 seconds after the application starts
3 Second execution of 10 seconds Job 10 seconds after the first execution
4 Second execution of 45 seconds Job 45 seconds after the first execution

Business logic in dedicated Use Cases

Although the previous example is valid, usually you don’t want to put your business logic in a Job. A better approach is to create an additional bean that the Job invokes. This approach decouples your business logic from the scheduling logic. Moreover, it facilitates testing and maintenance. Let’s see an example:

Create the following use case:

groovy/src/main/groovy/example/micronaut/EmailUseCase.groovy
package example.micronaut

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j

import jakarta.inject.Singleton
import java.text.SimpleDateFormat

@Slf4j
@CompileStatic
@Singleton
class EmailUseCase {

    void send(String user, String message) {
        log.info("Sending email to {}: {} at {}", user, message, new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
    }
}

And then the Job:

groovy/src/main/groovy/example/micronaut/DailyEmailJob.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.scheduling.annotation.Scheduled
import jakarta.inject.Singleton

@CompileStatic
@Singleton // 
class DailyEmailJob {

    protected final EmailUseCase emailUseCase

    DailyEmailJob(EmailUseCase emailUseCase) { // 
        this.emailUseCase = emailUseCase
    }

    @Scheduled(cron = "0 30 4 1/1 * ?") // 
    void execute() {
        emailUseCase.send("john.doe@micronaut.example", "Test Message") // 
    }
}
1 Use jakarta.inject.Singleton to designate a class as a singleton.
2 Constructor injection.
3 Trigger the Job once a day at 04:30 AM
4 Call the injected use case

Scheduling a Job Manually

Consider the following scenario. You want to send every user an email two hours after they register on your application and ask them about their experiences during this first interaction.

For this guide, we will schedule a Job to trigger after one minute.

To test it, we will call a new use case named RegisterUseCase twice when the application starts.

Modify Application.groovy:

groovy/src/main/groovy/example/micronaut/Application.groovy
package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.context.event.ApplicationEventListener
import io.micronaut.runtime.Micronaut
import io.micronaut.runtime.server.event.ServerStartupEvent
import jakarta.inject.Singleton

@CompileStatic
@Singleton // 
class Application implements ApplicationEventListener<ServerStartupEvent> {  // 

    private final RegisterUseCase registerUseCase

    Application(RegisterUseCase registerUseCase) { // 
        this.registerUseCase = registerUseCase
    }

    static void main(String[] args) {
        Micronaut.run(Application, args)
    }

    @Override
    void onApplicationEvent(ServerStartupEvent event) { // 
        try {
            registerUseCase.register("harry@micronaut.example")
            Thread.sleep(20000)
            registerUseCase.register("ron@micronaut.example")
        } catch (InterruptedException e) {
            e.printStackTrace()
        }
    }
}
1 Use jakarta.inject.Singleton to designate a class as a singleton.
2 Listen to the event ServerStartupEvent
3 Constructor injection of RegisterUseCase
4 onApplicationEvent is invoked when the application starts. Subscribing to an event is as easy as implementing ApplicationEventListener.

Create a runnable task EmailTask.groovy

groovy/src/main/groovy/example/micronaut/EmailTask.groovy
package example.micronaut

import groovy.transform.CompileStatic

@CompileStatic
class EmailTask implements Runnable {

    String email
    String message
    EmailUseCase emailUseCase

    @Override
    void run() {
        emailUseCase.send(email, message)
    }
}

Create RegisterUseCase.groovy, which schedules the previous task.

groovy/src/main/groovy/example/micronaut/RegisterUseCase.groovy
package example.micronaut

import groovy.transform.CompileStatic
import groovy.util.logging.Slf4j
import io.micronaut.scheduling.TaskExecutors
import io.micronaut.scheduling.TaskScheduler
import jakarta.inject.Named
import jakarta.inject.Singleton
import java.text.SimpleDateFormat
import java.time.Duration

@CompileStatic
@Slf4j
@Singleton
class RegisterUseCase {

    protected final TaskScheduler taskScheduler
    protected final EmailUseCase emailUseCase

    RegisterUseCase(EmailUseCase emailUseCase, // 
                    @Named(TaskExecutors.SCHEDULED) TaskScheduler taskScheduler) { // 
        this.emailUseCase = emailUseCase
        this.taskScheduler = taskScheduler
    }

    void register(String email) {
        log.info("saving {} at {}", email, new SimpleDateFormat("dd/M/yyyy hh:mm:ss").format(new Date()))
        scheduleFollowupEmail(email, "Welcome to the Micronaut framework")
    }

    private void scheduleFollowupEmail(String email, String message) {
        EmailTask task = new EmailTask(emailUseCase: emailUseCase, email: email, message: message) // 
        taskScheduler.schedule(Duration.ofMinutes(1), task) // 
    }
}
1 Constructor injection of EmailUseCase
2 Inject the TaskScheduler bean
3 Create a Runnable task
4 Schedule the task to run a minute from now

If you execute the above code, you will see the Job being executed one minute after we schedule it and with the supplied email address.

INFO  example.micronaut.RegisterUseCase - saving harry@micronaut.example at 15/5/2018 06:25:14
INFO  example.micronaut.RegisterUseCase - saving ron@micronaut.example at 15/5/2018 06:25:34
INFO  example.micronaut.EmailUseCase - Sending email to harry@micronaut.example : Welcome to Micronaut at 15/5/2018 06:26:14
INFO  example.micronaut.EmailUseCase - Sending email to ron@micronaut.example : Welcome to the Micronaut framework at 15/5/2018 06:26:34

Summary

During this guide, we learned how to configure Jobs using the @Scheduled annotation using fixedDelay, initialDelay, and cron, as well as manually configuring Jobs with a TaskScheduler and tasks.

Next Steps

Explore more features with Micronaut Guides.

Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

License

Note
 All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).