Groovy / Maven

Secure a Micronaut application with LinkedIn

Learn how to create a Micronaut application and authenticate with LinkedIn.

Sergio del Amo

On this guide

In this section

Getting Started

In this guide, we will create a Micronaut application written in Groovy.

What you will need

To complete this guide, you will need the following:

Some time on your hands
A decent text editor or IDE (e.g. IntelliJ IDEA)
JDK 21 or greater installed with JAVA_HOME configured appropriately

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Download and unzip the source

OAuth 2.0

To provide Sign in with LinkedIn with Authorization Code Flow, you need to visit linkedin.com/developers/ and:

Create a LinkedIn App

Configure Authorized Redirect URL

Go to the Auth tab.

Save your client ID and client secret. You will need them to configure your Micronaut application.
Register http://localhost:8080/oauth/callback/linkedin. By creating a client named linkedin in the Micronaut application, the route /oauth/callback/linkedin is registered.
After you add Add Sign in with LinkedIn, the scopes r_liteprofile and r_emailaddress will appear. We will configure the Micronaut application to request the r_liteprofile scope.

Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app example.micronaut.micronautguide \
    --features=security-oauth2,security-jwt,views-thymeleaf,reactor,serialization-jackson,http-client \
    --build=maven \
    --lang=groovy \
    --test=spock

Note	If you don’t specify the `--build` argument, Gradle with the Kotlin DSL is used as the build tool. If you don’t specify the `--lang` argument, Java is used as the language. If you don’t specify the `--test` argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

If you use Micronaut Launch, select Micronaut Application as application type and add security-oauth2, security-jwt, views-thymeleaf, reactor, serialization-jackson, and http-client features.

Note	If you have an existing Micronaut application and want to add the functionality described here, you can view the dependency and configuration changes from the specified features, and apply those changes to your application.

Diff

Setup IntelliJ IDEA to develop Micronaut Applications.

Views

Although the Micronaut framework is primarily designed around message encoding / decoding, there are occasions where it is convenient to render a view on the server side.

We’ll use the Thymeleaf Java template engine to render views.

Home

Create a controller to handle the requests to /. You will display the email of the authenticated person if any. Annotate the controller endpoint with @View since we will use a Thymeleaf template.

groovy/src/main/groovy/example/micronaut/HomeController.groovy

package example.micronaut

import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.annotation.Secured
import io.micronaut.security.rules.SecurityRule
import io.micronaut.views.View

@Controller // 
class HomeController {

    @Secured(SecurityRule.IS_ANONYMOUS) // 
    @View('home') // 
    @Get // 
    Map<String, Object> index() {
        [:]
    }
}

1	The class is defined as a controller with the @Controller annotation mapped to the path `/`.
2	Annotate with `io.micronaut.security.Secured` to configure secured access. The `SecurityRule.IS_ANONYMOUS` expression will allow access without authentication.
3	Use View annotation to specify which template to use to render the response.
4	The @Get annotation maps the `index` method to GET `/` requests.

Create a Thymeleaf template:

src/main/resources/views/home.html

<!DOCTYPE html>
<html xmlns:th="http://www.thymeleaf.org">
<head>
    <title>Home</title>
</head>
<body>
<h1>Micronaut - LinkedIn example</h1>

<h2 th:if="${security}">username: <span th:text="${security.name}"></span></h2>
<h2 th:unless="${security}">username: Anonymous</h2>

<nav>
    <ul>
        <li th:unless="${security}"><a href="/oauth/login/linkedin">Enter</a></li>
        <li th:if="${security}"><a href="/logout">Logout</a></li>
    </ul>
</nav>
</body>
</html>

Also, note that we return an empty model in the controller. However, we are accessing security in the Thymeleaf template.

The SecurityViewModelProcessor injects into the model a security map with the authenticated user. See User in a view documentation.

OAuth 2.0 authorization code grant flow

Here is a high level diagram of how the authorization code grant flow works with an OAuth 2.0 provider such as LinkedIn.

OAuth 2.0 Configuration

Add the following OAuth 2.0 configuration:

src/main/resources/application.properties

micronaut.security.authentication=cookie 
# 
micronaut.security.token.jwt.signatures.secret.generator.secret=${JWT_GENERATOR_SIGNATURE_SECRET:pleaseChangeThisSecretForANewOne} 
# 
micronaut.security.oauth2.clients.linkedin.client-id=${OAUTH_CLIENT_ID:xxx} 
micronaut.security.oauth2.clients.linkedin.client-secret=${OAUTH_CLIENT_SECRET:yyy} 
micronaut.security.oauth2.clients.linkedin.scopes[0]=r_liteprofile 
micronaut.security.oauth2.clients.linkedin.authorization.url=https://www.linkedin.com/oauth/v2/authorization 
micronaut.security.oauth2.clients.linkedin.token.url=https://www.linkedin.com/oauth/v2/accessToken 
micronaut.security.endpoints.logout.get-allowed=true

1	Set `micronaut.security.authentication` to `cookie` to generate a signed JWT once the user is authenticated. The token is saved in a cookie and read in subsequent requests.
2	You can create a SecretSignatureConfiguration named `generator` via configuration as illustrated above. The `generator` signature is used to sign the issued JWT claims.
3	Change this value to your own secret and keep it safe (do not store this in your VCS).
4	The provider identifier must match the last part of the URL you entered as a redirect URL: `/oauth/callback/linkedin`.
5	Client Secret. See previous screenshot.
6	Client ID. See previous screenshot.
7	Specify the scopes you want to request. LinkedIn Permission Types let you specify exactly what type of access you need.
8	Map the LinkedIn Authorization endpoint manually.
9	Map the LinkedIn Token endpoint manually.
10	Accept GET requests to the `/logout` endpoint.

The previous configuration uses several placeholders. You will need to set up the OAUTH_CLIENT_ID and OAUTH_CLIENT_SECRET environment variables.

export OAUTH_CLIENT_ID=XXXXXXXXXX
export OAUTH_CLIENT_SECRET=YYYYYYYYYY

OAuth 2.0 Details Mapper

We need an HTTP Client to retrieve the user info. Create a POJO to represent a LinkedIn user:

groovy/src/main/groovy/example/micronaut/LinkedInMe.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.core.annotation.NonNull
import io.micronaut.serde.annotation.Serdeable

import jakarta.validation.constraints.NotBlank

@CompileStatic
@Serdeable
class LinkedInMe {

    @NonNull
    @NotBlank
    final String id

    @NonNull
    @NotBlank
    final String localizedFirstName

    @NonNull
    @NotBlank
    final String localizedLastName

    LinkedInMe(@NonNull String id,
               @NonNull String localizedFirstName,
               @NonNull String localizedLastName) {
        this.id = id
        this.localizedFirstName = localizedFirstName
        this.localizedLastName = localizedLastName
    }
}

Then, create a Micronaut Declarative HTTP Client to consume LinkedIn Profile endpoint

groovy/src/main/groovy/example/micronaut/LinkedInApiClient.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Get
import io.micronaut.http.annotation.Header
import io.micronaut.http.client.annotation.Client
import org.reactivestreams.Publisher

@CompileStatic
@Client(id = 'linkedin') // 
interface LinkedInApiClient {

    @Get('/v2/me') // 
    Publisher<LinkedInMe> me(@Header String authorization) //  
}

1	Add the ID `linkedin` to the `@Client` annotation. Later, you will provide the URL for this client ID.
2	Define an HTTP GET request to the `/v2/me` endpoint.
3	You can return reactive types in a Micronaut declarative HTTP client.
4	You can specify that a parameter binds to an HTTP header, such as the Authorization header.

Specify the URL for the linkedin service.

src/main/resources/application.properties

micronaut.http.services.linkedin.url=https://api.linkedin.com

Create an implementation of OauthAuthenticationMapper. The implementation must be qualified by a name that matches the name present in the client configuration. The value specified in the client configuration is linkedin.

groovy/src/main/groovy/example/micronaut/LinkedInOauthAuthenticationMapper.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.core.annotation.Nullable
import io.micronaut.security.authentication.AuthenticationResponse
import io.micronaut.security.oauth2.endpoint.authorization.state.State
import io.micronaut.security.oauth2.endpoint.token.response.OauthAuthenticationMapper
import io.micronaut.security.oauth2.endpoint.token.response.TokenResponse
import jakarta.inject.Named
import jakarta.inject.Singleton
import org.reactivestreams.Publisher
import reactor.core.publisher.Mono

import static io.micronaut.http.HttpHeaderValues.AUTHORIZATION_PREFIX_BEARER

@CompileStatic
@Named('linkedin') // 
@Singleton // 
class LinkedInOauthAuthenticationMapper implements OauthAuthenticationMapper {

    private final LinkedInApiClient linkedInApiClient

    LinkedInOauthAuthenticationMapper(LinkedInApiClient linkedInApiClient) { // 
        this.linkedInApiClient = linkedInApiClient
    }

    @Override
    Publisher<AuthenticationResponse> createAuthenticationResponse(TokenResponse tokenResponse,
                                                                   @Nullable State state) {

        Mono.from(linkedInApiClient.me(AUTHORIZATION_PREFIX_BEARER + ' ' + tokenResponse.accessToken))
                .map(linkedMe -> {
                    Map<String, Object> attributes = [
                            'firstName': linkedMe.localizedFirstName,
                            'lastName': linkedMe.localizedLastName] as Map
                    String username = linkedMe.id
                    return AuthenticationResponse.success(username, Collections.emptyList(), attributes)
                })
    }
}

1	Declare `@Named` at the class level of a bean to explicitly define the name of the bean.
2	Use `jakarta.inject.Singleton` to designate a class as a singleton.
3	Use constructor injection to inject a bean of type `LinkedInApiClient`.

Running the Application

To run the application, use the ./mvnw mn:run command, which starts the application on port 8080.

Next Steps

Read Micronaut OAuth 2.0 documentation to learn more.

Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

License

Note	All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).