Groovy / Gradle

Session-based authentication

Learn how to secure a Micronaut application using session-based authentication.

Sergio del Amo

On this guide

In this section

Getting Started

In this guide, we will create a Micronaut application written in Groovy with session-based authentication.

The following sequence illustrates the authentication flow:

What you will need

To complete this guide, you will need the following:

Some time on your hands
A decent text editor or IDE (e.g. IntelliJ IDEA)
JDK 21 or greater installed with JAVA_HOME configured appropriately

Solution

We recommend that you follow the instructions in the next sections and create the application step by step. However, you can go right to the completed example.

Download and unzip the source

Writing the Application

Create an application using the Micronaut Command Line Interface or with Micronaut Launch.

mn create-app --features=security-session,views-velocity,reactor,graalvm example.micronaut.micronautguide --build=gradle --lang=groovy --test=spock

Note	If you don’t specify the `--build` argument, Gradle with the Kotlin DSL is used as the build tool. If you don’t specify the `--lang` argument, Java is used as the language. If you don’t specify the `--test` argument, JUnit is used for Java and Kotlin, and Spock is used for Groovy.

If you use Micronaut Launch, select "Micronaut Application" as application type and add the security-session, views-velocity, reactor, and graalvm features.

The previous command creates a Micronaut application with the default package example.micronaut in a directory named micronautguide.

Note	If you have an existing Micronaut application and want to add the functionality described here, you can view the dependency and configuration changes from the specified features, and apply those changes to your application.

Diff

Setup IntelliJ IDEA to develop Micronaut Applications.

Configuration

Add this configuration to application.properties:

groovy/src/main/resources/application.properties

micronaut.security.authentication=session 
micronaut.security.redirect.login-success=/ 
micronaut.security.redirect.login-failure=/login/authFailed

1	Set `micronaut.security.authentication` to `session`. It sets the necessary beans for login and logout using session-based authentication.
2	After the user logs in, redirect them to the Home page.
3	If the login fails, redirect them to /login/authFailed

Authentication Provider

To keep this guide simple, create a naive AuthenticationProvider to simulate user authentication.

groovy/src/main/groovy/example/micronaut/AuthenticationProviderUserPassword.groovy

package example.micronaut

import io.micronaut.core.annotation.NonNull
import io.micronaut.core.annotation.Nullable
import io.micronaut.http.HttpRequest
import io.micronaut.security.authentication.AuthenticationRequest
import io.micronaut.security.authentication.AuthenticationResponse
import io.micronaut.security.authentication.provider.HttpRequestReactiveAuthenticationProvider
import jakarta.inject.Singleton
import org.reactivestreams.Publisher
import reactor.core.publisher.Flux
import reactor.core.publisher.FluxSink

@Singleton // 
class AuthenticationProviderUserPassword<B> implements HttpRequestReactiveAuthenticationProvider<B> { // 

    @Override
    Publisher<AuthenticationResponse> authenticate(
            @Nullable HttpRequest<B> httpRequest,
            @NonNull AuthenticationRequest<String, String> authenticationRequest
    ) {
        Flux.create(emitter -> {
            if (authenticationRequest.identity == "sherlock" && authenticationRequest.secret == "password") {
                emitter.next(AuthenticationResponse.success((String) authenticationRequest.identity))
                emitter.complete()
            } else {
                emitter.error(AuthenticationResponse.exception())
            }
        }, FluxSink.OverflowStrategy.ERROR) as Publisher<AuthenticationResponse>
    }
}

1	Use `jakarta.inject.Singleton` to designate a class as a singleton.
2	A reactive Micronaut Authentication Provider implements the interface `io.micronaut.security.authentication.provider.HttpRequestReactiveAuthenticationProvider`.

Apache Velocity

By default, Micronaut controllers produce JSON. Usually, you consume those endpoints with a mobile phone application, or a JavaScript front end (Angular, React, Vue.js, etc.). However, to keep this guide simple, we will produce HTML in our controllers.

In order to do that, we use Apache Velocity and the Micronaut Server Side View Rendering Module.

Velocity is a Java-based template engine. It permits anyone to use a simple yet powerful template language to reference objects defined in Java code.

Create two Velocity templates in src/main/resources/views:

groovy/src/main/resources/views/home.vm

<!DOCTYPE html>
<html>
    <head>
        <title>Home</title>
    </head>
    <body>
        #if( $loggedIn )
            <h1>username: <span>$username</span></h1>
        #else
            <h1>You are not logged in</h1>
        #end
        #if( $loggedIn )
            <form action="logout" method="POST">
                <input type="submit" value="Logout"/>
            </form>
        #else
            <p><a href="/login/auth">Login</a></p>
        #end
    </body>
</html>

groovy/src/main/resources/views/auth.vm

<!DOCTYPE html>
<html>
    <head>
        #if( $errors )
            <title>Login Failed</title>
        #else
            <title>Login</title>
        #end
    </head>
<body>
    <form action="/login" method="POST">
        <ol>
            <li>
                <label for="username">Username</label>
                <input type="text" name="username" id="username"/>
            </li>
            <li>
                <label for="password">Password</label>
                <input type="password" name="password" id="password"/>
            </li>
            <li>
                <input type="submit" value="Login"/>
            </li>
            #if( $errors )
                <li id="errors">
                    <span style="color: red;">Login Failed</span>
                </li>
            #end
        </ol>
    </form>
</body>
</html>

Controllers

Create HomeController which resolves the base URL /:

groovy/src/main/groovy/example/micronaut/HomeController.groovy

package example.micronaut

import io.micronaut.core.annotation.Nullable
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.annotation.Secured
import io.micronaut.security.rules.SecurityRule
import io.micronaut.views.View

import java.security.Principal

@Secured(SecurityRule.IS_ANONYMOUS) // 
@Controller("/") // 
class HomeController {

    @Get("/") // 
    @View("home") // 
    Map<String, Object> index(@Nullable Principal principal) { // 
        Map<String, Object> data = ["loggedIn": principal != null]
        if (principal) {
            data.username = principal.name
        }
        data
    }
}

1	Annotate with `io.micronaut.security.Secured` to configure security access. Use `isAnonymous()` expression to allow access to authenticated and unauthenticated users.
2	Annotate with `io.micronaut.http.annotation.Controller` to designate the class as a Micronaut controller.
3	You can specify the HTTP verb that a controller action responds to. To respond to a GET request, use `io.micronaut.http.annotation.Get`
4	Use View annotation to specify which template to use to render the response.
5	If you are authenticated, you can use the `java.security.Principal` as a parameter type. For parameters which may be `null`, use `io.micronaut.core.annotation.Nullable`.

Next, create LoginAuthController which renders the login form.

groovy/src/main/groovy/example/micronaut/LoginAuthController.groovy

package example.micronaut

import groovy.transform.CompileStatic
import io.micronaut.http.annotation.Controller
import io.micronaut.http.annotation.Get
import io.micronaut.security.annotation.Secured
import io.micronaut.security.rules.SecurityRule
import io.micronaut.views.View

@CompileStatic
@Secured(SecurityRule.IS_ANONYMOUS) // 
@Controller("/login") // 
class LoginAuthController {

    @Get("/auth") // 
    @View("auth") // 
    Map<String, Object> auth() {
        [:]
    }

    @Get("/authFailed") // 
    @View("auth") // 
    Map<String, Object> authFailed() {
        [errors: true] as Map
    }
}

1	Annotate with `io.micronaut.security.Secured` to configure security access. Use `isAnonymous()` expression for anonymous access.
2	Annotate with `io.micronaut.http.annotation.Controller` to designate the class as a Micronaut controller.
3	Responds to GET requests at `/login/auth`
4	Use View annotation to specify which template to use to render the response.
5	Responds to GET requests at `/login/authFailed`

Tests

We also use Geb, a browser automation solution.

To use Geb, add these dependencies:

build.gradle

testImplementation("org.apache.groovy.geb:geb-spock:@geb-spockVersion@")
testImplementation("org.seleniumhq.selenium:htmlunit-driver:@htmlunit-driverVersion@")

Geb uses the Page concept pattern; the Page Object Pattern gives us a common sense way to model content in a reusable and maintainable way.

Create three pages:

src/test/groovy/example/micronaut/HomePage.groovy

package example.micronaut

import geb.Page

class HomePage extends Page {

    static url = '/'

    static at = { title == 'Home' }

    static content = {
        loginLink { $('a', text: 'Login') }
        logoutButton { $('input', type: 'submit', value: 'Logout') }
        usernameElement(required: false) { $('h1 span', 0) }
    }

    String username() {
        usernameElement.empty ? null : usernameElement.text()
    }

    void login() {
        loginLink.click()
    }

    void logout() {
        logoutButton.click()
    }
}

src/test/groovy/example/micronaut/LoginPage.groovy

package example.micronaut

import geb.Page

class LoginPage extends Page {

    static url = '/login/auth'

    static at = { title.contains 'Login' }

    static content = {
        usernameInput { $('#username') }
        passwordInput { $('#password') }
        submitInput { $('input', type: 'submit') }
        errorsLi(required: false) { $('li#errors') }
    }

    boolean hasErrors() {
        !errorsLi.empty
    }

    void login(String username, String password) {
        usernameInput = username
        passwordInput = password
        submitInput.click()
    }
}

src/test/groovy/example/micronaut/LoginFailedPage.groovy

package example.micronaut

import geb.Page

class LoginFailedPage extends Page {

    static at = { title == 'Login Failed' }

    static url = '/login/authFailed'
}

Create a test to verify the user authentication flow.

src/test/groovy/example/micronaut/SessionAuthenticationSpec.groovy

package example.micronaut

import geb.spock.GebSpec
import io.micronaut.runtime.server.EmbeddedServer
import io.micronaut.test.extensions.spock.annotation.MicronautTest
import jakarta.inject.Inject

@MicronautTest // 
class SessionAuthenticationSpec extends GebSpec {

    @Inject
    EmbeddedServer embeddedServer // 

    def "verify session based authentication works"() {
        given:
        browser.baseUrl = "http://localhost:${embeddedServer.port}"

        when:
        to HomePage

        then:
        at HomePage

        when:
        HomePage homePage = browser.page HomePage

        then: 'As we are not logged in, there is no username'
        homePage.username() == null

        when: 'click the login link'
        homePage.login()

        then:
        at LoginPage

        when: 'fill the login form, with invalid credentials'
        LoginPage loginPage = browser.page LoginPage
        loginPage.login('foo', 'foo')

        then: 'the user is still in the login form'
        at LoginPage

        and: 'and error is displayed'
        loginPage.hasErrors()

        when: 'fill the form with wrong credentials'
        loginPage.login('sherlock', 'foo')

        then: 'we get redirected to the home page'
        at LoginFailedPage

        when: 'fill the form with valid credentials'
        loginPage.login('sherlock', 'password')

        then: 'we get redirected to the home page'
        at HomePage

        when:
        homePage = browser.page HomePage

        then: 'the username is populated'
        homePage.username() == 'sherlock'

        when: 'click the logout button'
        homePage.logout()

        then: 'we are in the home page'
        at HomePage

        when:
        homePage = browser.page HomePage

        then: 'but we are no longer logged in'
        homePage.username() == null
    }
}

1	Annotate the class with `@MicronautTest` so the Micronaut framework will initialize the application context and the embedded server. More info.
2	Inject the `EmbeddedServer` bean.

Testing the Application

To run the tests:

./gradlew test

Then open build/reports/tests/test/index.html in a browser to see the results.

Running the Application

To run the application, use the ./gradlew run command, which starts the application on port 8080.

Next Steps

Explore more features with Micronaut Guides.

Help with the Micronaut Framework

The Micronaut Foundation sponsored the creation of this Guide. A variety of consulting and support services are available.

License

Note	All guides are released with an Apache License 2.0 for the code and a Creative Commons Attribution 4.0 license for the writing and media (images).